Dauerkalender

LED-Tester mit Stromanzeige

(mit 7-Segmentanzeige und LM317 als Konstantstromquelle)

Mit einem LED-Tester, der eine stufenlose Regelung des Stromes erlaubt, kann die benötigte Leuchtkraft einer Leuchtdiode exakt eingestellt werden. Anschließende Berechnung des richtigen Vorwiderstandes reduziert sich dann auf die wohlbekannte Grundformel R = U / I.
In der folgenden Schaltung regelt den Strom der Spannungsregler LM317, der hier mit lediglich einem Widerstand als Stromregler parametriert wird.
Ähnliche Schaltung haben wir auf der Seite

bereits realisiert.
Anstatt eines festen Widerstandes kommt diesmal ein Potentiometer, der eine stufenlose Einstellung des Stromes ermöglicht, zum Einsatz. Eine weitere Erweiterung der Schaltung stellt der Mikrocontroller Arduino Nano dar. Der Mikrocontroller misst den Spannungsabfall an dem Widerstand, der vor dem Regler LM317 vorgeschaltet wurde. Dieser Spannungsabfall ist direkt proportional zu dem Strom, der durch die Leuchtdiode, die untersucht wird, fließt. Aus dieser Abhängigkeit wird der aktuelle Strom errechnet und an die 7-Segmentanzeige weitergegeben.

LM317

Das Herzstück der Schaltung ist der Spannungsregler LM317. Dieser lineare Längsregler gehört mit seinen 46 Jahren (Baujahr 1976) zu den bekanntesten und erfolgreichsten Bauelementen der Elektronik.

Arduino Nano

Bezogen auf seine Möglichkeiten ist die Aufgabe, die der Mikrocontroller Arduino Nano hier zu bewältigen hat, ziemlich bescheidend. Es wird lediglich nur ein analoger Eingang in Anspruch genommen und eine einfache Rechenaufgabe durchgeführt.

Anzeige

Die 7-Segmentanzeige visualisiert das Ergebnis der Berechnungen. Hier handelt es sich um ein Modul, das aus vier Digits, die mit einem Doppelpunkt getrennt sind, besteht. Auf der Rückseite des Moduls sitz der Treiber TM1637, der die Ansteuerung der einzelnen Elemente der Anzeige übernimmt.

Der Schaltplan

Schaltplan

Um die Schaltung funktionstüchtig zusammenzustellen, sind einige Rechenaufgaben zu erledigen. Da eine hohe Genauigkeit bei einem einfachen LED-Tester nicht gefragt ist, können wir hier auf einiges verzichten.
Zunächst legen wir den Rahmen für die Aufgabe fest. Im ersten Schritt bestimmen wir, dass die Schaltung mit 9 VDC arbeiten soll. Im zweiten Schritt legen wir fest, dass die Leuchtdioden mit einem Strom im Bereich von 1 bis 20 mA getestet werden.
Der Strom, der durch die zu untersuchende LED fließt (LED1) ist gleich dem Strom, der durch den Widerstand R1 fließt. Den Wert des Stromes, der durch die Widerstände R4 und R5 entweicht, wird vernachlässigt. Bei solcher Annahme ist der Spannungsabfall am R1 proportional zu dem fließenden Strom und beträgt:

UR1 = I x R1

Da R1 bekannt ist (100 Ohm), kann man die Formel umstellen und den gesuchten Strom berechnen:

I = UR1 / R1

Um den Spannungsabfall zu ermitteln, wird das Potenzial hinter dem Widerstand R1 mithilfe von Arduino Nano gemessen. Er beträgt:

UR1 = 9 VDC – Ugemessen.

Die Spannung Ugemessen pendelt entsprechend unseren Vorgaben zwischen

9 VDC – R1 * 1 mA = 8,9 V

und

9 VDC – R1 * 20 mA = 7 V

Da Arduino Nano Spannungen von lediglich 5 V verträgt, muss diese Spannung angepasst werden. Das erledigt der Spannungsteiler R4-R5, der die Spannung halbiert.
Der Wert des Widerstandes R1 beträgt 100 Ohm. Bei einem Spannungsabfall von 2 V (9 V – 7 V) und einem Strom von 20 mA muss er mit einer Verlustleistung von 2 V * 20mA = 0,04 W fertig werden.
Auch etwas Mathematik erwartet uns bei der Bestimmung des Potetiometers, mit dem der Strom eingestellt wird. Der Widerstand, mit dem der Strom eingestellt wird, pendelt zwischen 62,5 Ohm (20 mA) und 1250 Ohm (1 mA).

Diese Grenzwerte erreichen wir, indem drei Potentiometer (P1, P2, P3) gemischt wie auf dem Schaltplan verschaltet werden. Der Potentiometer P3 (0 – 2 kOhm) ist unser Einstellpotentiometer. P1 und P2 werden auf feste Werte eingestellt.
Die untere Grenze von 62,5 Ohm erreichen wir, indem der Potentiometer P1 eben auf diesen Wert eingestellt wird. Wenn P3 auf 0 Ohm gedreht wird (Nullstellung), beträgt der Gesamtwert 62,5 Ohm.:

Rges = P1 + P2//P3 = 62,5 + (P2*P3 / P2+P3) = 62,5 + 0 = 62,5 Ohm

Den Potentiometer P2 stellen wir auf den Wert von 2920 Ohm. Wenn P3 auf 2000 Ohm gedreht wird (Vollausschlag) ergibt sich folgender Gesamtwert:

Rges = P1 + P2//P3 = 62,5 + (P2*P3 / P2+P3) = 62,5 + 1187 = 1250 Ohm

Die Testschaltung

Testschaltung

Das Programm (Sketch)

#include <TM1637Display.h>                                  // Display Bibliothek
#define CLK 10                                              // Display Pin CLK
#define DIO 11                                              // Display Pin DIO
                                                            
TM1637Display display(CLK, DIO);
int AnalogPin = A0;                                         // Analoger Eingang
float Spannung;                                             
float Strom;
float Offset = 0.4;  
String Ausgabe;     
int Mittelwert [10];

                                                      
void setup() {
    display.setBrightness(10);                              // Anzeige Helligkeit
    display.clear();                                        // Display löschen
}

void loop() {

    Spannung = analogRead(AnalogPin);                       // Spannungswert auslesen
    for (int i=0; i<9; i++) {                               // Werte in der Mittelwert Tabelle schieben
      Mittelwert [i] = Mittelwert [i+1];
    }
    Mittelwert [9] = Spannung;                              // Neuer Wert in die Mittelwerttabelle
    Spannung = 0;
    for (int i=0; i<10; i++) {                              // Werte aus der Mittelwerttabelle addieren
      Spannung = Spannung + Mittelwert [i];
    }
    Spannung = Spannung / 10;                               // Spannung Mittelwert berechnen (gemessen)
     
    Spannung = (4.5 - (Spannung * 5) / 1023) * 1000;        // Spannung ausrechnen (*1000 wegen Komma)
    Strom = (Spannung / 50);                                // Strom berechnen
    Strom = Strom - Offset;                                 // Offset Korrektur
    if (Strom < 1 ) { Strom = 1; }                          // 0-Anzeige eliminieren
    
    Ausgabe = String (Strom);                               // Display Anzeige
    display.showNumberDecEx(Ausgabe.toInt(), 0b00000000, false, 4, 4);     
    delay(500);                                             // Wartezeit 0,5 sek
   
}
// **************************************************************************************          

Das Programm erledigt drei Aufgaben:

1. Mittelwert
Um die Schwankungen bei der Spannungsmessung zu minimieren, wird aus den letzten 10 Messungen ein Mittelwert berechnet. Die Messungen erfolgen in dem 0,5-Sek.-Takt.

2. Berechnung des Stromes
Mit
Spannung = (4.5 - (Spannung * 5) / 1023) * 1000;
wird der Spannungsabfall an dem Widerstand R1 berechnet. Bei dem analogen Wert von 1023 liegt an dem analogen Eingang eine Spannung von 5V an. Gemessene Spannung beträgt demnach:
Ugemessen = Spannung-Wert * 5 / 1023
Die gemessene Spannung wird von der Versorgungsspannung abgezogen. Da die Spannung halbiert ist, lautet die Rechnung:
USpannungsabfall = 4,5 – Ugemessen
Die Multiplikation mit 1000 dient lediglich dazu, die Kommastelle nach rechts zu schieben.
Der Strom wird dann nach folgender Formel berechnet:
Strom = (Spannung / 50);
Da Spannungen halbiert wurden, muss auch der Widerstandswert halbiert werden (100 / 2 = 50.
Bei bedarf kann man die Ergebnisse mit einem Offset zusätzlich justieren.

3. Ausgabe des Ergebnisses an die Anzeige

Kurzvideo zur Schaltung

Kurzvideo

Stromregler